Crux Saturn Assignment: CAS Transactions

earth pluto mercury neptune saturn jupiter comet

Introduction

This is the cas (compare and swap) installment of the Crux tutorial.

We shall assume you have a Crux standalone node set up locally and are now comfortable with put operations and basic Datalog queries. If this is not the case, you can find all you need to know on Earth, Pluto and Mercury. Click on a destination above to take you there.

Arrival on Saturn

As you pass through the innermost ring of Saturn, A warning light appears on your communications panel. You open the message. It’s from Space Customs and reads:

We extend you the warmest welcome.

We must check papers before we can give you permission to land.

— Cronus Peaceful Nations

They are asking to see your flight manifest.

Choose your path:

You have your manifest You do not have your manifest

You have permission to land

You do not have permission to land. You must return to Neptune and fill in your manifest.

saturn

neptune

Space Port

As you prepare to land you open your Crux manual to the page on Compare and Swap (cas)

Currently there are only four transaction operations in Crux: put, delete, cas and evict.

Transaction Description

put

Writes a version of a document

delete

Deletes a version of a document

cas

Writes new version of a document if the old version is as expected.

evict

Removes a document entirely

CAS:

The CAS operation (compare and swap) swaps an existing document version with a newer one, if the existing document is as expected.

Along with the old doc and the new doc cas, like put, gives you the option of providing a start and an end valid-time.

Time in Crux is denoted #inst "yyyy-MM-ddThh:mm:ss". For example, 9:30 pm on January 2nd 1999 would be written:

#inst "1999-01-02T21:30:00".

A complete cas transaction has the form:

[:crux.tx/cas old-doc new-doc valid-time-start valid-time-end]

If the old-doc does not match the one stored in Crux at the given valid time then the operation will not be performed. If there are multiple operations in the same transaction then none of these will happen either.

Note that if there is no old-doc in Crux, you can provide nil in its place.

— Crux manual
Read More

Assignment

As you land on the surface of Saturn the job ticket for this assignment is unlocked.


Ticket
Task

Secure trading system

Company

Cronus Market Technologies

Contact

Ubuku Eppimami

Submitted

2115-02-23T13:38:20

Additional information

We need to be shown how to ensure no trades are done without the buyer and seller having the necessary funds or stock respectively

Attachments

example_data


The next shuttle to the CMT office leaves in 5 Earth minutes. While you wait you use your easy ingest function you created on Pluto to put the example data into your system. You also decide to make some Clojure functions so you can easily show Ubuku the stock and fund levels after the trades.

(defn stock-check
  [company-id item]
  {:result (crux/q (crux/db crux)
                   {:find '[name funds stock]
                    :where ['[e :company-name name]
                            '[e :credits funds]
                            ['e item 'stock]]
                    :args [{'e company-id}]})
   :item item})


(defn format-stock-check
  [{:keys [result item] :as stock-check}]
  (for [[name funds commod] result]
    (str "Name: " name ", Funds: " funds ", " item " " commod)))

Just as you are finishing off your shuttle arrives.

After a short journey through the icy lower clouds of Saturn you are met by a friendly faced Ubuku.

Hello friend.

We have been using Crux for a short time now and think it is great. The problem is a human one. Occasionally we process trades without checking that are enough funds in the buyers account.

I know there is a way that we can stop this happening in Crux.

I sent you some example data in the job ticket for you to use, did you find it alright?

— Ubuku Eppimami
CMT

Choose your path

"Yes, I’m ready to fix your problem." "No, I seem to have missed that."
pluto surface

You explain to Ubuku that all they need to do to solve their problem is to use the cas operation instead of put when they are processing their trades.

You show Ubuku the cas operation for a valid transaction. You move 10 units of Methane (:units/CH4) each at the cost of 100 credits to Blue Energy:

(crux/submit-tx
 crux
 [[:crux.tx/cas
   ;; Old doc
   {:crux.db/id :blue-energy
    :seller? false
    :buyer? true
    :company-name "Blue Energy"
    :credits 1000}
   ;; New doc
   {:crux.db/id :blue-energy
    :seller? false
    :buyer? true
    :company-name "Blue Energy"
    :credits 900
    :units/CH4 10}]

  [:crux.tx/cas
   ;; Old doc
   {:crux.db/id :tombaugh-resources
    :company-name "Tombaugh Resources Ltd."
    :seller? true
    :buyer? false
    :units/Pu 50
    :units/N 3
    :units/CH4 92
    :credits 51}
   ;; New doc
   {:crux.db/id :tombaugh-resources
    :company-name "Tombaugh Resources Ltd."
    :seller? true
    :buyer? false
    :units/Pu 50
    :units/N 3
    :units/CH4 82
    :credits 151}]])

You explain that because the old doc is as expected for both the buyer and the seller that the transaction goes through.

You show Ubuku the result of the trade using the function you created earlier:

  (format-stock-check (stock-check :tombaugh-resources :units/CH4))
  => ("Name: Tombaugh Resources Ltd., Funds: 151, :units/CH4 82")

  (format-stock-check (stock-check :blue-energy :units/CH4))
  => ("Name: Blue Energy, Funds: 900, :units/CH4 10")

They are happy that this works as he sees the 1000 credits move from Blue energy to Tombaugh Resources Ltd. and 10 units of Methane the other way.

Ubuku asks if you can show them what would happen if there was not enough funds in the account of a buyer. You show him a trade where the old doc is not as expected for Encompass trade, to buy 10,000 units of Gold from Gold Harmony.

(crux/submit-tx
 crux
 [[:crux.tx/cas
   ;; Old doc
   {:crux.db/id :gold-harmony
    :company-name "Gold Harmony"
    :seller? true
    :buyer? false
    :units/Au 10211
    :credits 51}
   ;; New doc
   {:crux.db/id :gold-harmony
    :company-name "Gold Harmony"
    :seller? true
    :buyer? false
    :units/Au 211
    :credits 51}]

  [:crux.tx/cas
   ;; Old doc
   {:crux.db/id :encompass-trade
    :company-name "Encompass Trade"
    :seller? true
    :buyer? true
    :units/Au 10
    :units/Pu 5
    :units/CH4 211
    :credits 100002}
   ;; New doc
   {:crux.db/id :encompass-trade
    :company-name "Encompass Trade"
    :seller? true
    :buyer? true
    :units/Au 10010
    :units/Pu 5
    :units/CH4 211
    :credits 1002}]])
  (format-stock-check (stock-check :gold-harmony :units/Au))
  => ("Name: Gold Harmony, Funds: 51, :units/Au 10211")

  (format-stock-check (stock-check :encompass-trade :units/Au))
  => ("Name: Encompass Trade, Funds: 1002, :units/Au 10")

You explain to Ubuku that this time, because you have both cas operations in the same transaction, the trade does not go through. The accounts remain the same, even though the failing cas was the second operation.

Ubuku thanks you. This is just what they are looking for. You head back to the space station to see if there is another assignment waiting for you.

Space Port

Back at the spaceship there is a light waiting for you on your communications panel.

Well done, you’ve had a productive week. We have one final task for you to do before you finish for the week

You need to go to Jupiter and meet Kaarlang, it’s his last day working for us and he needs to delete his trade clients from his personal Crux node for data protection.

— Helios Banking Inc.

Update Manifest

You update your manifest with your most recent badge.

(crux/submit-tx
 crux
 [[:crux.tx/put
   (assoc manifest :badges ["SETUP" "PUT" "DATALOG-QUERIES" "BITEMP" "CAS" ])]])

As you do so, you check to see if you still have the note that the porter gave you for Kaarlang back on Earth.

  (crux/q (crux/db crux)
          {:find '[belongings]
           :where '[[e :cargo belongings]]
           :args [{'belongings "secret note"}]})

  => #{["secret note"]}

Feeling a bit apprehensive, you enter countdown for lift off to Jupiter. See you soon.

Click on Jupiter to take you to your next assignment.

jupiter

Published: 2019-07-22

Privacy policy

joa
by Johanna Antonelli
Published: 2019-07-22
joa
by Johanna Antonelli
Published: 2019-07-22
joa
by Johanna Antonelli
Published: 2019-07-22